#!/usr/bin/perl -w
#
# na-rcli.pl - written by Andrew Sullivan, 2010-02-08
#
# Please report bugs and request improvements at http://get-admin.com/blog/?p=947
#
# The NetApp SDK can be found here: http://communities.netapp.com/docs/DOC-1110
#
# Options are:
#   --hostname|-H = (mandatory) hostname or IP of NetApp to connect to
#   --username|-u = (mandatory) username to connect with
#   --password|-p = (optional)  password for user, will be prompted if not supplied
#   --protocol|-P = (optional)  Currently only HTTP and HTTPS are available, HTTPS
#                                 is the default
#
# Examples:
#   na-rcli.pl --hostname my_filer --username not_root --password some_secret
#     This will result in you connecting to the host using the HTTPS protocol.
#
#   na-rcli.pl -H my_filer -u not_root -P HTTP
#     Short method of connecting, will prompt for password and use HTTP connection
#
# TODO:
#   Add support for batch mode
#   Add support for SSH as the transport method
#
# You may need to uncomment this line and correct the path if the NetApp Perl SDK
# is not available in your default Perl library path.
#use lib "./NetApp";
 
use strict;
use Getopt::Long qw(:config no_ignore_case);
 
use NaServer;
use NaElement;
 
main( );
 
sub main {
	my $opts = parse_options();
	$opts->{ 'privState' } = "admin";
 
	my $server = getFiler( $opts->{ 'hostname' }, $opts->{ 'username' }, $opts->{ 'password' }, $opts->{ 'protocol' } );
 
	# some nice data to print for the user
	my $ontap = ( getOnTAP( $server ) =~ /NetApp Release (.*?):/ ? $1 : "unknown" ); 
 
	my $hostname = executeCli( $server, $opts, "hostname" );
	chomp( $hostname );
	$opts->{ 'hostname' } = $hostname;
 
	print "\n\tWelcome to the NetApp rCLI!\n";
	print "Connected to " . $hostname . ", OnTAP " . $ontap . ", using " . $opts->{ 'protocol' } . "\n";
	print "\tType \"exit\" to leave the rCLI." . "\n\n";
	print prompt( $opts );
 
	# loop until we break on purpose, accepting input from the user.  Ctrl-C will exit the program.
	# Fortunately, there is no state...each command is a seperate entity which reconnects and 
	# reauthenticates against the NetApp each time.  This means we don't have to trap interrupts
	# in order to cleanup after ourselves and prevent lingering connections.
	while ( my $line  = <STDIN> ) {
		chomp($line);
 
		# exit if requested
		if ( $line =~ /[Ee][Xx][Ii][Tt]/ ) {
			last;
		}
 
		# passthrough if empty line
		if ( $line eq "" || ! $line ) {
			next;
		}
 
		# execute our request
		my $result = executeCli( $server, $opts, $line );
 
		# show the goods
		print $result;
 
	} continue {
		# check for one of the priv elevation states
		#print "  Continue: " . $line . "\n";
		if ( $line =~ /^priv set\s*(.*)$/ ) {
			my $state = $1;
			chomp($state);
 
			if ( $state ne "admin" && $state ne "diag" && $state ne "advanced" ) {
				$state = "admin";
			}
 
			$opts->{ 'privState' } = $state;
 
		}
 
		# show the prompt each time
		print prompt( $opts );
	}
}
 
sub prompt {
	my ($opts) = @_;
 
	my $priv = ($opts->{ 'privState' } eq "advanced" || $opts->{ 'privState' } eq "diag") ? '*' : '';
 
	# create the default prompt
	return $opts->{ 'username' } . "@" . $opts->{ 'hostname' } . $priv . "> ";
}
 
sub getFiler {
	my ($hostname, $username, $password, $protocol) = @_;
 
	my $s = NaServer->new($hostname, 1, 3);
	$s->set_style('LOGIN');
	$s->set_admin_user($username, $password);
	$s->set_transport_type($protocol);
 
	return $s;
}
 
sub executeCli {
	my ($server, $opts, $command) = @_;
 
	# form our request
	my $request = NaElement->new('system-cli');
	my $args = NaElement->new('args');
 
	my $executable = split_string( $command );
 
	for my $arg ( @{ $executable } ) {
		$args->child_add_string('arg', $arg);
	}
 
	$request->child_add($args);
 
	# elevate our priv level, if needed
	if ( $opts->{ 'privState' } ne "admin" ) {
		$request->child_add_string('priv', $opts->{ 'privState' });
	}
 
	# execute and print an error or the result from the NetApp
	my $result = $server->invoke_elem($request);
 
	if ($result->results_errno != 0) {
		print STDERR 'Invoke failed! Reason: ' . $result->results_reason() . "\n";
		print STDERR 'Exiting rCLI...';
		exit(1);
	} else {
		return $result->child_get_string('cli-output');
	}
}
 
# extracting out the passed command, taking into account quoted strings that should
# be passed as a single argument
sub split_string {
	# loosely based on http://www.perlmonks.org/?node_id=552969
    my $text = shift;
    my @new = ();
 
	push(@new, $+) while $text =~ /(
		# groups the phrase inside double quotes
		"([^\"\\]*(?:\\.[^\"\\]*)*)"\s?
		# groups the phrase inside single quotes
		| '([^\'\\]*(?:\\.[^\'\\]*)*)'\s?
		# unquoted strings
		| ([^\s]+)\s?
		)/gx;
 
	return \@new;
}
 
sub getOnTAP {
	my ($server) = @_;
 
	my $request = NaElement->new('system-get-version');
	my $result = $server->invoke_elem($request);
 
	if ($result->results_errno != 0) {
		print STDERR 'Invoke failed! Reason: ' . $result->results_reason() . "\n";
		exit(1);
	} else {
		return $result->child_get_string('version');
	}
 
}
 
sub parse_options {
 
	my %options = (
		'hostname'  => '',
		'username'  => '',
		'password'  => '',
		'protocol'  => 'HTTPS',
		'help'      => 0
	);
 
	GetOptions( \%options,
		'hostname|H=s',
		'username|u=s',
		'password|p:s',
		'protocol|P:s',
		'help|h'
	);
 
	if (! $options{ 'hostname' } || ! $options{ 'username' } || $options{ 'help' }) {
		print_usage();
		exit(1);
	}
 
	$options{'protocol'} = uc( $options{'protocol'} );
 
	# default to HTTP protocol
	if ( $options{'protocol'} ne "HTTP" || $options{'protocol'} ne "HTTPS" ) {
		$options{'protocol'} = "HTTP";
	}
 
	if (! $options{ 'password' }) {
		print "Enter password: ";
		if ( $^O eq "MSWin32" ) {
			require Term::ReadKey;
 
			Term::ReadKey->import( qw(ReadMode) );
			Term::ReadKey->import( qw(ReadLine) );
			ReadMode('noecho');
 
			chomp( $options{ 'password' } = ReadLine(0) );
 
			ReadMode('normal');
 
		} else {
			system("stty -echo") and die "ERROR: stty failed\n";
			chomp ( $options{ 'password' } = <STDIN> );
			system("stty echo") and die "ERROR: stty failed\n";
		}
 
		print "\n";
	}
 
	return \%options;
}
 
sub print_usage {
	print <<EOU
  Missing or incorrect arguments!
 
  na-rcli.pl --hostname|-H <hostname> 
             --username|-u <username> 
           [ --password|-p <password> ]
		   [ --protocol|-P HTTP|HTTPS ]
 
  na-rcli.pl --help|-h
 
EOU
 
}